socsvn commit: r270315 - soc2014/kczekirda/pxe-fai-head/others
kczekirda at FreeBSD.org
kczekirda at FreeBSD.org
Wed Jul 2 09:29:00 UTC 2014
Author: kczekirda
Date: Wed Jul 2 09:28:59 2014
New Revision: 270315
URL: http://svnweb.FreeBSD.org/socsvn/?view=rev&rev=270315
Log:
mfsbsd menu
Added:
soc2014/kczekirda/pxe-fai-head/others/mfsbsd.ipxe
Added: soc2014/kczekirda/pxe-fai-head/others/mfsbsd.ipxe
==============================================================================
--- /dev/null 00:00:00 1970 (empty, because file is newly added)
+++ soc2014/kczekirda/pxe-fai-head/others/mfsbsd.ipxe Wed Jul 2 09:28:59 2014 (r270315)
@@ -0,0 +1,130 @@
+#!ipxe
+
+cpuid --ext 29 && set CPU-ARCH amd64 || set CPU-ARCH i386
+
+:start
+set def http://mfsbsd.vx.sk
+menu Welcome to iPXE's mfsBSD Boot Menu (contact: kczekirda at freebsd.org)
+item
+item --gap -- ----------------------- mfsBSD mirror -----------------------------------
+item http://czyki.no-ip.info kczekirda mirror: http://czyki.no-ip.info
+item http://mfsbsd.vx.sk Default mirror: http://mfsbsd.vx.sk
+item other Change mirror
+item --gap -- -------------------------------------------------------------------------
+item shell Enter iPXE shell
+item reboot Reboot
+item exit Exit (boot local disk)
+item --gap -- -------------------------------------------------------------------------
+
+choose --timeout 5000 --default ${def} sel || exit
+
+iseq ${sel} other && goto other ||
+iseq ${sel} shell && goto shell ||
+iseq ${sel} reboot && goto reboot ||
+iseq ${sel} exit && goto exit ||
+goto default
+
+:other
+echo Please enter your mfsBSD mirror (for example: http://example.com)
+echo Files should be plased in http://example.com/files/iso/..
+read mirror
+goto series
+
+:default
+set mirror ${sel}
+
+iseq ${mirror} http://czyki.no-ip.info && goto kczekirda || goto series
+
+:kczekirda
+set def 10
+menu Welcome to iPXE's mfsBSD Boot Menu (contact: kczekirda at freebsd.org)
+item
+item --gap -- ------------------------ mfsBSD releases --------------------------------
+item 11 11.0
+item 10 10.0
+item 9 9.2
+item 8 8.4
+item --gap -- -------------------------------------------------------------------------
+
+choose --timeout 5000 --default ${def} sel && goto ${sel} || exit
+
+:series
+set def 10
+menu Welcome to iPXE's mfsBSD Boot Menu (contact: kczekirda at freebsd.org)
+item
+item --gap -- ------------------------ mfsBSD releases --------------------------------
+item 10 10.0
+item 9 9.2
+item 8 8.4
+item --gap -- -------------------------------------------------------------------------
+
+choose --timeout 5000 --default ${def} sel && goto ${sel} || exit
+
+:11
+set ver 11
+set pocz 11.0-CURRENT
+set def r267488
+menu Welcome to iPXE's mfsBSD Boot Menu (contact: kczekirda at freebsd.org)
+item
+item --gap -- -------------------- mfsBSD CURRENT versions ----------------------------
+item r267488 r267488
+item r267488 r267488 with serial console
+item r266655 r266655
+item r266655-fai r266655 Fully Automatic Installer
+item --gap -- -------------------------------------------------------------------------
+choose --timeout 5000 --default ${def} sel
+
+set ver2 ${pocz}-${sel}
+goto standard
+
+:10
+set ver 10
+set ver2 10.0-RELEASE
+goto edition
+
+:9
+set ver 9
+set ver2 9.2-RELEASE
+goto edition
+
+:8
+set ver 8
+set ver2 8.4-RELEASE
+goto edition
+
+:edition
+iseq ${mirror} http://czyki.no-ip.info && goto standard ||
+set def standard
+menu Welcome to iPXE's mfsBSD Boot Menu (contact: kczekirda at freebsd.org)
+item
+item --gap -- ---------------- mfsBSD standard vs special edition ---------------------
+item standard standard
+item se special edition
+item --gap -- -------------------------------------------------------------------------
+
+choose --timeout 5000 --default ${def} sel && goto ${sel} || exit
+
+:standard
+set iso ${mirror}/files/iso/${ver}/${CPU-ARCH}/mfsbsd-${ver2}-${CPU-ARCH}.iso
+goto boot
+
+:se
+set iso ${mirror}/files/iso/${ver}/${CPU-ARCH}/mfsbsd-se-${ver2}-RELEASE-${CPU-ARCH}.iso
+goto boot
+
+:boot
+kernel http://volt.iem.pw.edu.pl/~czekirdk/memdisk iso raw
+initrd ${iso}
+boot
+
+:shell
+echo Type exit to get the back to the menu
+shell
+set menu-timeout 0
+goto start
+
+:reboot
+reboot
+
+:exit
+sanboot --no-describe --drive 0x80
More information about the svn-soc-all
mailing list